TRS-80 en France

Visites

Visiteurs
45
Articles
206
Liens internet
9
Compteur d'affichages des articles
355923

 

une carte prototype 512Ko compatible SUPERMEN

But:

  1. Offrir la possibilité de travailler avec 512Ko de mémoire RAM sur les micro-ordinateurs TRS-80 Modèle I
  2. Pouvoir récupérer les softwares déjà existants
  3. Garder une trace de notre patrimoine numérique
  4. Mettre à disposition un schéma pour le dépannage et comprendre le fonctionnement de la carte.
  5. N'utiliser qu'un type de GAL20V8 contrairement à la carte Supermen ou 2 types de PAls sont utilisées.

La programmation des GAL a été réalisé par Régis Munoz.

Un orifice dans le PCB a été réalisé pour le passage d'une grande colonette du fond de boitier (contrairement à la carte SUPERMEN qui oblige de couper cette grande colonnette).
Attention tous les composants excepté le Z80 doivent être montés sans supports
 

Vue de la carte prototype

Carte fixée sur la carte mère

Modification dans le fond du boitier

Il faut raccourcir de quelques millimètres une très courte colonnette avec un forêt

Demo.

Demo 01

Demo 02

Les Branchements de la carte

Le câblage est identique à la notice de câblage de la carte SUPERMEN pour raison de compatibilité.

mais le prototype d'un banc de mémoire sans coupure du PCB est à l'étude.

Carte Prototype 512K

 

Name     SM_G20V8 ;
PartNo   01 ;
Date     06/12/2015 ;
Revision 01 ;
Designer Regis MUNOZ ;
Company  University of Tulsa ;
Assembly None ;
Location None ;
Device   g20v8a ;

/*****************************************************************/
/*                                                                  */
/*          Carte prototype 512ko for TRS-80 Model-1                   */
/*            GAL modele g20v8 : Remplace IC1 PAL20R4              */
/*                                                                  */
/*****************************************************************/

/** PROPERTY Atmel {JTAG=OFF};             **/
/** PROPERTY Atmel {SLOW_INLATCH=ON};        **/


/* *************** INPUT PINS *********************/

PIN 1   = CLK;        /* Register Clock = /MREQ */
PIN 2   = AD6;        /* Z80 - AD6              */
PIN 3   = AD4;     /* Z80 - AD4              */
PIN 4   = AD3;     /* Z80 - AD3              */
PIN 5   = AD2;     /* Z80 - AD2              */
PIN 6   = AD1;     /* Z80 - AD1              */
PIN 7   = AD0;     /* Z80 - AD0              */
PIN 8   = RFSH;     /* Z80 - /RFSH            */
PIN 9   = WR;             /* Z80 - /WR              */
PIN 10  = IORQ;     /* Z80 - /IORQ            */
PIN 11  = AD7;     /* Z80 - AD7              */
PIN 13  = !out_enable;/* Output Enable = /RFSH  */
PIN 14  = AD14;     /* Z80 - AD14             */
PIN 23  = AD5;     /* Z80 - AD5              */


/* *************** OUTPUT PINS ********************/

PIN 15  = IO_15;    /* Output I/O-15          */
PIN 16  = IO_16;    /* Output I/O-16          */
PIN 19  = RF19;        /* Register Outputs RF19  */
PIN 20  = RF20;    /* Register Outputs RF20  */
PIN 21  = ORANGE;    /* Orange                 */
PIN 22  = IO_22;    /* Output I/O-22          */


/* ***************** EQUATIONS ********************/
!IO_22 = AD7 & !AD6 & !AD5 & !AD4 & !AD3 & AD2 & !AD1 & !AD0 & !WR & !IORQ;
IO_22.oe = 'b'1;      /* Connect to VCC */

!ORANGE = !AD14;
ORANGE.oe = RFSH;

!RF20.d = !RF20 & RF19 # RF20 & !RF19;
/* Default connect : RF20.oe = out_enable;  tri-state control on Z80-RFSH signal */

!RF19.d = AD6 & AD5 & AD4 & AD3 & AD2 & AD1 & AD0 & !RFSH;
/* Default connect : RF19.oe = out_enable;  tri-state control on Z80-RFSH signal */

!IO_16 = !AD7 & AD6 & !AD5 & !AD4 & !AD3 & !AD2 & AD1 & AD0 & !IORQ;
IO_16.oe = 'b'1;      /* Connect to VCC */

!IO_15 = !AD7 & AD6 & !AD5 & !AD4 & !AD3 & !AD2 & AD1 & AD0 & !WR & !IORQ;
IO_15.oe = 'b'1;      /* Connect to VCC */


/* ******************** END ***********************/

 

Name     SM_G20XV10TOG20V8A ;
PartNo   01 ;
Date     06/12/2015 ;
Revision 01 ;
Designer Regis MUNOZ ;
Company  University of Tulsa ;
Assembly None ;
Location None ;
Device   g20v8a ;

/********************************************************************/
/*                                                                  */
/*         Carte prototype 512ko for TRS-80 Model-1                       */
/*        Version GAL20V8A pour remplacer  IC6 PAL20L10                */
/*                                                                    */
/* ATTENTION la modification des Equations impose une modification    */
/* de PINs sur le PCB.                                                */
/* Il faut donc modifier la connexion de 5 pins entre la GAL20XV10     */
/* et la GAL20V8A:                                                    */
/*                                                                    */
/*        SIGNAL        GAL20VX10    GAL20V8A                            */
/*        ---------------------------------                            */
/*        AD15        PIN 13         PIN 14                                */
/*        SET_MEM        PIN 14         PIN 15                                */
/*        ROM_A        PIN 15      PIN 16                                */
/*        K1            PIN 22         PIN 21                                */
/*        OUT_CAS        PIN 23         PIN 22                                */
/*                                                                  */
/********************************************************************/

/** PROPERTY Atmel {JTAG=OFF};             **/
/** PROPERTY Atmel {SLOW_INLATCH=ON};    **/

/* *************** INPUT PINS *******************/
PIN 1   = DD0;        /* Z80 - DD0                  */
PIN 2   = DD1;        /* Z80 - DD1                  */
PIN 3   = DD2;         /* Z80 - DD2                  */
PIN 4   = DD3;         /* Z80 - DD3                  */
PIN 5   = DD4;         /* Z80 - DD4                  */
PIN 6   = DD5;         /* Z80 - DD5                  */
PIN 7   = MUX;         /* MUX - K6 (Z72 pin3)        */
PIN 8   = IO_22;     /* IO_22/DD0 - IC3A           */
PIN 10  = IN_ROMA;     /* to pin15                    */
PIN 11  = IN_CAS;     /* IN CAS - K5 (Z72 pin10)    */
PIN 14  = AD15;        /* Z80 - AD15                */


/* *************** OUTPUT PINS ******************/
PIN 15  = SET_MEM;    /* Set Memory - K4 (pin15)    */
PIN 16  = ROM_A;    /* ROM A - K7 (Z74 pin 10)    */
PIN 19  = IO16;        /* f16                        */
PIN 17  = IO17;        /* f17                        */
PIN 18  = A8;        /* A8 - K2 (pin1 RAM sock)    */
PIN 20  = IO21;        /* f21                        */
PIN 21  = K1;        /* K1 (Z51 pin13)             */
PIN 22  = OUT_CAS;    /* OUT CAS - K3 (Z67 pin13)    */


/* ***************** EQUATIONS ******************/
!IO16 = !DD0 & !DD1 & !DD2 & !DD3 & !DD4;
IO16.oe = 'b'1;          /* Connect to VCC */

!IO17 = (!DD5 & !AD15) # (DD5 & AD15);
IO17.oe = 'b'1;          /* Connect to VCC */

!IO21 = (!DD3 & !DD4) # !IO17;
IO21.oe = 'b'1;          /* Connect to VCC */

!OUT_CAS = (!IO21 & IO_22 & !IN_CAS) # (!IO21 & !IN_ROMA & !IN_CAS);
OUT_CAS.oe = 'b'1;      /* Connect to VCC */

!K1 = (!DD0 & IO17 & IO16) # (!DD5 & !AD15) # (!IO16 & !AD15);
K1.oe = 'b'1;              /* Connect to VCC */

!A8 = (!DD1 & !MUX) # (!DD2 & MUX) # !IO17;
A8.oe = 'b'1;              /* Connect to VCC */

!ROM_A = 'b'1;          /* Connect to VCC */
ROM_A.oe = AD15;

!SET_MEM = (DD3 & !DD4 & IO17 & IO_22 & !IN_CAS) # (DD3 & !DD4 & IO17 & !IN_ROMA & !IN_CAS);
SET_MEM.oe = 'b'1;      /* Connect to VCC */

/* ******************** END ***********************/

 

Le schéma, programmation des GALs et les Gerbers de cette carte sont gratuitement à votre disposition  dans le menu Downloads

 Certains textes et certaines images présentes sur mon site
sont peut être encore sous Copyright de leurs éditeurs et auteurs respectifs.
Si ces derniers le désirent, je les retirerai immédiatement

ph@prof-80.fr