TRS-80 en France

Visites

Visiteurs
45
Articles
206
Liens internet
9
Compteur d'affichages des articles
355914

Doubleur_NEW_PERC

Nous avons  construit Régis MUNOZ et moi une carte prototype basée sur le principe de fonctionnement de la carte de référence pour les doubleurs de Densité "La PERCOM II "

 But:

  1. Pouvoir récupérer les softwares déjà existants
  2. Garder une trace de notre patrimoine numérique
  3. Mettre à disposition un schéma pour le dépannage et comprendre le fonctionnement de la carte.

Cahier des charges:

  1. Être compatible au maximum avec une carte PERCOM II
  2. Fonctionner sans réglage (plug and play)
  3. Supprimer le fonctionnement de la carte avec une "PROM" aujourd'hui introuvable.
  4. Utiliser des composants faciles d'approvisionnement.
  5. Utiliser des composants d'un prix modique.
  6. Rester dans l'esprit des années 70/80
  7. Utiliser des dimensions pour être utilisées dans une carte d'expansion MDX-2
  8. Bannir tous les composants exotiques
  9. Les composants à programmer devront être programmable avec un programmateur très bas de gamme.
  10. ...etc

Pour cela nous avons utilisé des "GAL16V8" d'approvisionnements très faciles, programmables avec des programmateurs de quelques dizaines d'Euros. Nous avons écarté les "PAL" et "PROM" qui ne sont programmables qu'une unique fois. Les "GAL" sont programmables X fois et donc récupérables sur des vieilles cartes électroniques.

Je me suis chargé de la partie "hard" et Régis de la partie "Soft"

Vue de dessus

Vue de dessous

Comparaison avec un Doubleur PERCOM

Equations pour la GAL IC4

Designer Regis MUNOZ ;
Company University of Tulsa ;
Assembly None;
Location None;
Device g16v8a;
/********************************************* */
/* */
/* GAL for Doubler_New_Perc_A card */
/* ----------- Regis MUNOZ ----------- */
/* */
/* GAL # 2 : DECODAGE & LOGIC - IC4 */
/* */
/********************************************* */
/*************** INPUTS PINS ******************/
Pin 1 = in_r5c7; /* Input between R5/C7 */
Pin 2 = in_r6c6; /* Input between R6/C6 */
Pin 3 = wd; /* Input WD signal of PIN-31 of IC2 - FD1791 */
Pin 4 = late; /* Input LATE signal of PIN-18 FD1791 */
Pin 5 = early; /* Input EARLY signal of PIN-17 FD1791 */
Pin 6 = a0; /* Input A0 signal */
Pin 7 = a1; /* Input A1 signal */
Pin 8 = dal3; /* Input DAL3 signal */
Pin 9 = dal4; /* Input DAL4 signal */
Pin 11 = dal5; /* Input DAL5 signal */
Pin 12 = dal6; /* Input DAL6 signal */
Pin 13 = dal7; /* Input DAL7 signal */
Pin 14 = we; /* Input WE signal */
Pin 17 = in_r1c2; /* Input between R1/C2 */
/*************** OUTPUTS PINS ***************/
Pin 15 = out_ic1_3; /* To PIN-3 of IC1 */
Pin 16 = out_r1; /* To R1 */
Pin 18 = dwd; /* To PIN-10 of IC10 */
Pin 19 = out_r5r6; /* To R5/R6 */
/** Logic Equations **/
out_r5r6 = wd;
dwd = (in_r6c6 & !early & !late) # (in_r5c7 & !early & late) # (wd
& early & !late);
out_r1 = !we;
out_ic1_3 = !(in_r1c2 & !(we # dal3) & !(dal6 # dal7) & !(dal4 # dal5) &
!(a0 # a1));
/* ******************** END ***********************/

Equations pour la GAL IC9

Name      NewPercA;
Partno    NEWPERCA-RM;
Date      20/06/16;
Revision  05;
Designer  Regis MUNOZ ;
Company   University of Tulsa ;
Assembly  None;
Location  None;
Device    g16v8a;

/*********************************************    */
/*                                             */
/*        GAL for Doubler_New_Perc_A card           */
/*    ----------- Regis MUNOZ -----------     */
/*                            */
/*      GAL # 1 : CLOCK GENERATOR - IC9        */
/*                            */
/*********************************************    */

/*************** INPUTS PINS ******************/
Pin 1     = clk;         /* Entree Clock 4/8MHz */
Pin 2    = LD;        /* To PIN-15 of this GAL */
Pin 3    = IC5_9;    /* To PIN-9 of IC5 */
Pin 4    = IC5_8;    /* To PIN-8 of IC5 */
Pin 5    = IC7_8;    /* To PIN-8 of IC7    */
Pin 6    = IC7_5;    /* To PIN-5 of IC7    */
Pin 7    = IC7_9;    /* To PIN-9 of IC7    */
Pin 8    = WF_VFOE;    /* To resistor 4.7k and signal WF/VFOE# of IC2 */
Pin 11    = !oe;         /* To GND : Register output enable */

/*************** OUTPUTS PINS ***************/
Pin 12 = RCLK;    /* Output RCLK signal */
Pin 13 = FDDATA;    /* Output FDDATA signal */
Pin 14 = FDCLK;    /* Output FDCLK signal */
Pin 15 = OLD;        /* To PIN-2 of this GAL */
Pin 16 = Q3;        /* To PIN-11 of IC5 (input clock)*/
Pin 17 = Q2;        /* NC (do not connect) */
Pin 18 = Q1;        /* NC (do not connect) */
Pin 19 = Q0;        /* NC (do not connect) */

/** Declarations and Intermediate Variable Definitions **/
Field count = [Q3..0];    /* inputs table of counter */
Field prom = [K3..0];    /* outputs table of counter */

TABLE count => prom {
'd'0 => 'h'1;        /* 0001 */
'd'1 => 'h'1;        /* 0001 */
'd'2 => 'h'2;        /* 0010 */
'd'3 => 'h'3;        /* 0011 */
'd'4 => 'h'3;        /* 0011 */
'd'5 => 'h'4;        /* 0100 */
'd'6 => 'h'4;        /* 0100 */
'd'7 => 'h'4;        /* 0100 */
'd'8 => 'h'E;        /* 1110 */
'd'9 => 'h'E;        /* 1110 */
'd'10 => 'h'E;        /* 1110 */
'd'11 => 'h'E;        /* 1110 */
'd'12 => 'h'F;        /* 1111 */
'd'13 => 'h'F;        /* 1111 */
'd'14 => 'h'0;        /* 0000 */
'd'15 => 'h'1;        /* 0001 */
}

/** Logic Equations **/
OLD    = !(IC7_5 & IC7_9);
FDDATA    = !(IC5_9 # IC7_8);
FDCLK    = !(IC5_8 # IC7_8);
RCLK    = !(IC5_9 # WF_VFOE);

/* Inputs Data of counter (clock) */
Q0.d = (!LD & K0) # (LD & !Q0);
Q1.d = (!LD & K1) # (LD & !Q1 & Q0) # (LD & Q1 & !Q0);
Q2.d = (!LD & K2) # (LD & Q2 & !Q1) # (LD & Q2 & !Q0) # (LD & !Q2 & Q1 & Q0);
Q3.d = (!LD & K3) # (LD & Q3 & !Q2) # (LD & Q3 & !Q1) # (LD & Q3 & !Q0) # (LD & !Q3 & Q2 & Q1 & Q0);

 

Le schéma, les Gerbers et fichiers .JED de cette carte sont gratuitement à votre disposition  dans le menu Downloads

Certains textes et certaines images présentes sur mon site
sont peut être encore sous Copyright de leurs éditeurs et auteurs respectifs.
Si ces derniers le désirent, je les retirerai immédiatement

Email: ph@prof-80.fr